Filtres de Wikidata útils per la versió catalana de la Viquipèdia

Filtres de Wikidata útils per la versió catalana de la Viquipèdia
El Query de Wikidata permet filtrar els elements de Wikidata per tal d'obtenir-ne informació rellevant.
Podeu veure un exemple aquí, on es filtren aquells articles de persones catalanoparlants que existeixen a la versió catalana i anglesa però amb nom diferent, per tal de detectar casos de castellanització del nom.

A continuació es mostren alguns filtres similars que poden ser útils.

Llista de catalanoparlants


Codi:

# Get a list with all Catalan speakers
SELECT ?item ?itemLabel ?itemDescription
WHERE {
  ?item wdt:P31 wd:Q5 .       # Humans
  ?item wdt:P1412 wd:Q7026 .  # Language Spoken: Catalan
  SERVICE wikibase:label
    {
      bd:serviceParam wikibase:language "ca" .
      ?item rdfs:label ?itemLabel .
      ?item schema:description ?itemDescription .
    }
}


Articles de catalanoparlants que tenen article a la versió anglesa però no a la versió catalana


Codi:

# Get articles about Catalan people which exist in the Catalan version but not in the English version of Wikipedia
SELECT ?item ?itemLabel ?itemDescription
WHERE {
  ?item wdt:P31 wd:Q5 .       # Humans
  ?item wdt:P27 wd:Q29 .      # Country of Citizenship: Spain
  ?item wdt:P1412 wd:Q7026 .  # Language Spoken: Catalan
  FILTER EXISTS {
    ?item ^schema:about ?enArticle . # Buscar versió anglesa
    ?enArticle schema:isPartOf <https://en.wikipedia.org/> .
  }
  FILTER NOT EXISTS {
    ?item ^schema:about ?caArticle . # Buscar versió catalana
    ?caArticle schema:isPartOf <https://ca.wikipedia.org/> .
  }
  SERVICE wikibase:label
    {
      bd:serviceParam wikibase:language "ca" .
      ?item rdfs:label ?itemLabel .
      ?item schema:description ?itemDescription .
    }
}


Nota: Intercanviant les línies "FILTER EXISTS" i "FILTER NOT EXISTS" es pot obtenir el cas contrari, és a dir, aquells que tenen la versió catalana però no l'anglesa.

Llista de persones nascudes a Catalunya


Només s'obté una llista d'aquelles persones que són citades específicament com a "Lloc de naixement: Catalunya", no aquelles on se cita la ciutat, poble o regió concrets.
La categoria sempre descriu el lloc de naixement de la manera més precisa possible, per tant les persones llistades són aquelles que se sap que van néixer a Catalunya però no se sap exactament on.

Codi:

# Humans listed as "Born in Catalonia"
select distinct ?item ?itemLabel ?itemDescription ?sitelinks where {
  ?item wdt:P31 wd:Q5;  # Any instance of a human.
    wdt:P19 wd:Q5705;   # Who was born in Catalonia.
    wikibase:sitelinks ?sitelinks.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ca" }
}
ORDER BY DESC(?sitelinks)


Llista de municipis i entitats territorials administratives de Catalunya


Codi:

# List of municipalities and administrative territorial entities of Catalonia
SELECT DISTINCT ?item ?place WHERE {
  hint:Query hint:optimizer "None".
  VALUES ?territory { wd:Q33146843 wd:Q11917457 }
  ?item wdt:P31* ?territory .
  ?article schema:about ?item ; schema:isPartOf <https://ca.wikipedia.org/> ;  schema:name ?place .
}


En cas de voler una llista més completa de territoris de parla catalana, amb comarques i províncies, i incloent no només Catalunya sinó altres regions (País Valencià, Illes Balears...), s'inclou un codi ampliat a continuació.

Per la manera com funcionen les categories d'aquestes regions a WikiData, és probable que hi faltin noms de ciutats de les regions que no són Catalunya. Per aquest motiu, han estat desactivades del codi.

Codi:

# Llista de regions que inclouen el català com a llengua nativa
#  Nota: S'han inclòs manualment les categories de WikiData que fan referència a regions de parla catalana
#  Tot i això, és possible que hi falti algun territori.
# Autor: Wecoc
# Data: 13 de maig de 2022

SELECT DISTINCT ?item ?place WHERE {
  hint:Query hint:optimizer "None".
  # A continuació es descriu quins territoris afegir a la llista
  # Podeu desactivar aquells que no us interessin fent servir '#' Al principi de la línia
  VALUES ?territory {
    # Catalunya
    wd:Q5705        # Catalunya
      wd:Q7194      # Província de Girona
      wd:Q13904    # Província de Lleida
      wd:Q98392    # Província de Tarragona
      wd:Q81949    # Província de Barcelona
    wd:Q33146843    # Llista de municipis de Catalunya
    wd:Q11917457    # Llista de divisions territorials de Catalunya (barris de Barcelona, etc.)
    wd:Q937876      # Llista de comarques de Catalunya
   
    # País Valencià
#    wd:Q5720        # País Valencià
#      wd:Q54936    # Província d'Alacant
#      wd:Q54942    # Província de Castelló
#      wd:Q54939    # Província de València
#    wd:Q766277      # Llista de comarques del País Valencià
   
    # Andorra
#    wd:Q228        # Andorra
#    wd:Q24279      # Llista de parròquies d'Andorra
#    wd:Q41108733    # Llista de municipis d'Andorra
   
    # Pirineus orientals
#    wd:Q12709      # Pirineus orientals
#      wd:Q701082    # Districte de Ceret
#      wd:Q702066    # Districte de Perpinyà
#      wd:Q702122    # Districte de Prada
#      wd:Q15475    # Vallespir
#      wd:Q15479    # Cerdanya francesa
#      wd:Q15477    # Conflent
   
    # Altres territoris / categories
#    wd:Q166282      # L'Alguer
#    wd:Q107356467  # Illes balears
#      wd:Q107356469 # Província de les illes balears
#    wd:Q15579      # La Franja
#    wd:Q1765102    # El Carxe
  }
  ?item wdt:P31* ?territory .
  ?article schema:about ?item ; schema:isPartOf <https://ca.wikipedia.org/> ;  schema:name ?place .
}